@echo off& setlocal enableextensions enabledelayedexpansion
(set v=*& set n=*)
:M
title=OpenFolder& color 07& mode con cols=68 lines=17& echo.
echo Open a folder. ^(is not tested with PE v7, CS v4^).
echo.
echo Example:  6 ^(PE v6^)
echo Example: -7 ^(PS v7^)
echo Example: +3 ^(CS v3^)
echo.
echo.
(set /p v=  Photoshop Ver? [PE: X / PS: -X / CS: +X]: )
if "!v:~,1!"=="*" goto e
set a=.!v:*.=!&rem remove any extension
(set a=& if defined v set v=!v:%a%=!)
title=/%v%/%n%/ OpenFolder.cmd by Benny Pedersen, www.fineraw.com
color 70& cls& echo.
if "!v:~,1!"=="-" (
	echo.  Folder to open ^(Photoshop !v:~1!^)
) else (if "!v:~,1!"=="+" (
	echo.  Folder to open ^(Photoshop CS!v:~1!^)
) else	echo.  Folder to open ^(Photoshop Elements !v!^))
echo.
echo.  1: Actions     atn
echo.  2: Brushes     abr
echo.
echo.  3: Cache       db3 ^(che when PSE ver less than 5^)
echo.  4: Camera Raw  8bi
echo.
echo.  5: Required
echo.  6: "%programfiles%\Adobe\"  ^(Adobe DNG Converter^)
echo.
echo.  7: Catalogs ^(tested with PE v5^)
echo.  8: XML      ^(tested with PE v6 and Vista^)
echo.& (set /p n=  Option Num? [*/ Enter: !n!]: )
if "!n:~,1!"=="*" goto e
if "!v:~,1!"=="-" (set v=!v:~1!& call:%n%ps "start explorer" "adobe\photoshop"& set v=-!v!) else (
if "!v:~,1!"=="+" (set v=!v:~1!& call:%n%cs "start explorer" "Photoshop"& set v=+!v!) else call:%n%pe "start explorer" "adobe\photoshop elements")
goto M
:1pe
  if !v! leq 4 (
	if !v! geq 3 (set v=!v!.0)
	for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!" %~1 "%%~F !v!\previews\effects"
  ) else (
    if !v! equ 5 (
	for %%F in ("%allusersprofile%\application data\%~2") do (
		if exist "%%~F\!v!.0" (
			if exist "%%~F\!v!.0\photo creations\special effects\All What I Need" (
				%~1 /select,"%%~F\!v!.0\photo creations\special effects\All What I Need"
			)else 	%~1 "%%~F\!v!.0\photo creations\special effects"
		)
	)
    )else (
	for %%F in ("%allusersprofile%\application data\%~2") do (
	if exist "%%~F\!v!.0" %~1 "%%~F\!v!.0\photo creations\photo effects")
    )
  )
exit /b
:2pe
	if !v! geq 3 (set v=!v!.0)
	for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!" %~1 "%%~F !v!\presets\brushes"
exit /b
:3pe
  if !v! lss 5 (
	if !v! gtr 2 (set v=!v!.0)
	for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!" %~1 "%%~F !v!\previews\cache"
  )else for %%F in ("%allusersprofile%\application data\%~2") do if exist "%%~F\!v!.0" %~1 "%%~F\!v!.0"
exit /b
:4pe
	if !v! gtr 2 (set v=!v!.0)
	for %%F in ("%programfiles%\%~2") do (
		if exist "%%~F !v!" (
			if exist "%%~F !v!\Plug-Ins\File Formats\Camera Raw.8bi" (
				%~1 /select,"%%~F !v!\Plug-Ins\File Formats\Camera Raw.8bi"
			)else	%~1 "%%~F !v!\Plug-Ins\File Formats"
		)
	)
exit /b
:5pe
	if !v! geq 3 (set v=!v!.0)
	for %%F in ("%programfiles%\%~2") do (
		if exist "%%~F !v!" (
			if exist "%%~F !v!\Required\BatchWin.atn" (
				%~1 /select,"%%~F !v!\Required\BatchWin.atn"
			)else	%~1 "%%~F !v!\Required"
		)
	)
exit /b
:1ps
for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!.0" %~1 "%%~F !v!.0\presets\photoshop actions"
exit /b
:2ps
for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!.0" %~1 "%%~F !v!.0\presets\brushes"
exit /b
:3ps
exit /b
:4ps
for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!.0" %~1 "%%~F !v!.0\Plug-Ins\File Formats"
exit /b
:5ps
for %%F in ("%programfiles%\%~2") do if exist "%%~F !v!.0" %~1 "%%~F !v!.0\Required"
exit /b
:1cs
for %%F in ("%programfiles%\adobe\Adobe") do (
if !v! gtr 2 (if exist "%%~F %~2 CS!v!" %~1 "%%~F %~2 CS!v!\Presets\Actions"
) else (if exist "%%~F %~2 CS!v!" %~1 "%%~F %~2 CS!v!\presets\%~2 actions"
if exist "%%~F%~2CS!v!" %~1 "%%~F%~2CS!v!\presets\%~2 actions"
))
exit /b
:2cs
for %%F in ("%programfiles%\adobe\Adobe") do (
if exist "%%~F %~2 CS!v!" %~1 "%%~F %~2 CS!v!\presets\brushes"
if exist "%%~F%~2CS!v!" %~1 "%%~F%~2CS!v!\presets\brushes")
exit /b
:3cs
if !v! lss 3 (
if exist "%APPDATA%\Adobe\CameraRaw\Cache" %~1 "%APPDATA%\Adobe\CameraRaw\Cache"
) else (if exist "%TMP%\..\Application Data\Adobe\CameraRaw\Cache" (
%~1 "%TMP%\..\Application Data\Adobe\CameraRaw\Cache"
))
exit /b
:4cs
if !v! gtr 2 (%~1 "%CommonProgramFiles%\Adobe\Plug-Ins\CS3\File Formats"
) else (for %%F in ("%programfiles%\adobe\Adobe") do (
if exist "%%~F %~2 CS!v!" %~1 "%%~F %~2 CS!v!\Plug-Ins\File Formats"
if exist "%%~F%~2CS!v!" %~1 "%%~F%~2CS!v!\Plug-Ins\File Formats"
))
exit /b
:5cs
for %%F in ("%programfiles%\adobe\Adobe") do (
if exist "%%~F %~2 CS!v!" %~1 "%%~F %~2 CS!v!\Required"
if exist "%%~F%~2CS!v!" %~1 "%%~F%~2CS!v!\Required")
exit /b
:6pe
if exist "%programfiles%\%~2 !v!.0" (
%~1 /select,"%programfiles%\%~2 !v!.0"
) else goto 6ps
exit /b
:6ps
%~1 "%programfiles%\Adobe\"
exit /b
:6cs
if exist "%programfiles%\Adobe\Adobe %~2 CS!v!" (
%~1 /select,"%programfiles%\Adobe\Adobe %~2 CS!v!"
) else goto 6ps
exit /b
:7pe
%~1 "%allusersprofile%\application data\adobe\catalogs\"
exit /b
:8pe
if !v! lss 6 exit /b
if exist "%allusersprofile%\Adobe\Photoshop Elements\!v!.0\Locale\en_US\Photo Creations Metadata\photo effects\" (
	 %~1 "%allusersprofile%\Adobe\Photoshop Elements\!v!.0\Locale\en_US\Photo Creations Metadata\photo effects"
) else (if exist "%allusersprofile%\Adobe\Photoshop Elements\!v!.0\Locale\en_US" (
%~1 /select,"%allusersprofile%\Adobe\Photoshop Elements\!v!.0\Locale\en_US"
))
:8ps
exit /b
:e
endlocal